$! 01-AUG-2000 [pr] adding crates to 45 & removing some duplicated #s
$! 21-JUN-2000 [pr] adding crates 30 & 31 to GKB2
$!                     eliminating first few duplicate crate numbers
$! 20-APR-2000 [pr] modifying crates created so 61 and 62 only show up once
$! 11-Feb-2000 [pr] add GKC2
$! 01-Oct-1999 [pr] upped gkb2 crates from 1:18 to 1:30
$! 16-Aug-1999 [pr] upped gkb2 crates from 1:14 to 1:18
$! 04-Aug-1999 [pr] upped gkb2 crates from 1:8 to 1:14
$! 14-Jul-1999 [pr/tgc] back to GKB, switched when mem was installed
$! 31-Mar-1999 [pr/trg] trying GKC
$! 30-Mar-1999 [pr] first UltraSCSI card replaced today with NCR 53C810
$!                  testing original CAMAC config
$! edit: 04-Jan-99 [pr] putting in immediate exit, and adding defn
$!                      of NSTX$STARTUP for use later
$! 23-Dec-98 [pr] CAMAC moved to MEL until KEES SCSI buses replaced
$! edit: 21-Dec-98 [pr] now using SCSI_CAMSHR instead of JORWAY_CAMSHR
$!                    per J.Stillerman; SCSI_CAMSHR is from 20-Nov-98
$!                    MIT build - allows Jorway or Kinetics on any bus,
$!                    and does NOT try to permit bus sharing: problem with
$!                    DEC driver leads to "Medium not available" and hang
$! edit: 22-May-98 [pr] putting in MDSplus definitions and defining CTS
$! 12-Jan-1998 [PR] Create MANGO CAMAC startup based on info from JAS
$!  MANGO has a Jorway xxxx Serial Highway Driver with Block Transfer
$! JORWAY added to MANGO SCSI bus as device number 2
$!
$!
$!
$ create/name_table/parent=lnm$system_directory/protection=(w:rwed,g:rwed) -
         lnm_camac  ! Create logical name table for CAMAC names
$ define/system/nolog/exec camshr SYS$SHARE:SCSI_CAMSHR
$ define/system/nolog/exec NSTX$STARTUP KEES0:[NSTX.NSTX.STARTUP]
$ deas/table=lnm_camac/all
$
$!  3/30/99$! --------- JAN 1999 --- NO CAMAC YET ON KEES -------
$!  3/30/99$    EXIT
$!
$!
$!---------------- Add Crates Below this line ----------------------------
$
$ call add_crates GKB2  1  3
$ call add_crates GKB2  9 15
$ call add_crates GKB2 18 19
$ call add_crates GKB2 22 23
$ call add_crates GKB2 25 27
$ call add_crates GKB2 31 35
$ call add_crates GKB2 36 45
$ call add_crates GKB2 61 61
$!
$ call add_crates GKC2  4  8
$ call add_crates GKC2 16 17
$ call add_crates GKC2 20 21
$ call add_crates GKC2 24 24
$ call add_crates GKC2 28 30
$ call add_crates GKC2 36 45
$ call add_crates GKC2 62 62
$
$!------------------------------------------------------------------------
$! Install MDSplus images that require it
$ @AUTIL:[MDSPLUS]MDSPLUS.COM	; defines CTS
$!
$ CTS
AUTOCONFIGURE
SET */ON
SHOW/CRATE
EXIT
$!
$ exit
$
$ def_crate_sub: subroutine
$ driver = P1+"00"
$ if .not. f$getdvi(driver+":","exists") then mcr sysman io connect 'driver'/noadapter/driver=sys$gkdriver
$ crate = f$fao("!2ZL",f$integer(P2))
$ define/table=lnm_camac/nolog 'P1''crate': crate'crate'
$ exit
$ endsubroutine
$
$ add_crates: subroutine
$ add_crate := call def_crate_sub
$ idx = f$integer(p2)
$ endidx = f$integer(p3)
$ add_crates_loop:
$ if idx .gt. endidx then exit
$ add_crate 'P1' 'idx'
$ idx = idx + 1
$ goto add_crates_loop
$ exit
$ endsubroutine
$