!--------------------------
real(fp) FUNCTION SVRC_JANEV(ZTE)
!  ZTE IN EV
!  SVRC_JANEV IN CM**3/SEC
!
!  JANEV-LANGER-EVANS, ELEMENTARY PROCESSES IN HYDROGEN/HELIUM PLASMAS
!     (Springer Verlag 1987) p. 32
!
!  MAXWELLIAN AVG  summed over states (1,2p,2s,3...10)
!
!============
! idecl:  explicitize implicit INTEGER declarations:
  use iso_c_binding, only: fp => c_double
  use physconst_mod, only : zero,half,one,two
  USE expint1
  IMPLICIT NONE
  INTEGER i
!============
! idecl:  explicitize implicit REAL declarations:
  real(fp) zte
!============
  real(fp) AS(3),CHIS(3),ZNFAC(3)
  real(fp) zbeta,ze1
!
  DATA AS/3.92e-14_fp,2.47e-14_fp,6.22e-14_fp/
                                        ! Anl in reference:  1s, 2s, 2p
  DATA CHIS/0.35_fp,0.12_fp,0.61_fp/
                                        ! chi(nl) in reference:  1s, 2s, 2p
  DATA ZNFAC/one,half,half/
                                        ! sqrt(En(ion)/Ry) = 1/n, cf reference
!
  SVRC_JANEV=zero
  do i=1,3
     ZBETA=ZNFAC(i)*ZNFAC(i)*13.58_fp/ZTE
     SVRC_JANEV=SVRC_JANEV+&
          AS(i)*ZNFAC(i)*ZBETA**1.5_fp/(ZBETA+CHIS(i))
  enddo
!
  do i=3,10
     ZBETA=13.58_fp/(i*i*ZTE)
     ZE1=EXPI1S(ZBETA)   ! r8slatec-derived exponential integral eval.
     SVRC_JANEV=SVRC_JANEV+&
          5.201e-14_fp*ZBETA**1.5_fp*ZE1*EXP(ZBETA)
  enddo
!
  RETURN
END FUNCTION SVRC_JANEV
!--------------------------
real(fp) FUNCTION SVEIH_JANEV(ZTE)
  use iso_c_binding, only: fp => c_double
!  ZTE IN EV
!  SVEIH_JANEV IN CM**3/SEC
!
!  JANEV-LANGER-EVANS, PPPL-TM-368 P.281, REACTION A1.5
!  IONIZATION OF H(1S) QUANTUM STATE
!  BY ELECTRON IMPACT, MAXWELLIAN AVG
!
!  results match <sigma*v> data shown at:
!  JANEV-LANGER-EVANS, ELEMENTARY PROCESSES IN HYDROGEN/HELIUM PLASMAS
!     (Springer Verlag 1987) p. 27
!
!============
! idecl:  explicitize implicit INTEGER declarations:
  IMPLICIT NONE
  INTEGER i
!============
! idecl:  explicitize implicit REAL declarations:
  real(fp) zte,zlt,zls
!============
  real(fp) A15(9)
  DATA A15/&
       -3.271397e+01_fp, 1.353656e+01_fp,-5.739329_fp,&
       1.563155_fp,-2.877056e-01_fp, 3.482560e-02_fp,&
       -2.631976e-03_fp, 1.119544e-04_fp,-2.039150e-06_fp/
!
  ZLT=log(ZTE)
!
  ZLS=A15(9)
  DO I=8,1,-1
     ZLS=ZLS*ZLT+A15(I)
  enddo
!
  SVEIH_JANEV=EXP(ZLS)
!
  RETURN
END FUNCTION SVEIH_JANEV
!--------------------------
real(fp) FUNCTION SVEIHE_JANEV(ZTE)
  use iso_c_binding, only: fp => c_double
!  ZTE IN EV
!  SVEIHE_JANEV IN CM**3/SEC
!
!  JANEV-LANGER-EVANS, PPPL-TM-368 P.288, REACTION A3.9
!  IONIZATION OF ATOMIC HE(1S2|1S) QUANTUM STATE
!  BY ELECTRON IMPACT, MAXWELLIAN AVG
!
!  results match <sigma*v> data shown at:
!  JANEV-LANGER-EVANS, ELEMENTARY PROCESSES IN HYDROGEN/HELIUM PLASMAS
!     (Springer Verlag 1987) p. 91
!
!============
! idecl:  explicitize implicit INTEGER declarations:
  IMPLICIT NONE
  INTEGER i
!============
! idecl:  explicitize implicit REAL declarations:
  real(fp) zte,zlt,zls
!============
  real(fp) A39(9)
  DATA A39/&
       -4.409865e+01_fp, 2.391597e+01_fp,-1.075323e+01_fp,&
       3.058039_fp,-5.685119e-01_fp, 6.795391e-02_fp,&
       -5.009056e-03_fp, 2.067236e-04_fp,-3.649161e-06_fp/
!
  ZLT=log(ZTE)
!
  ZLS=A39(9)
  DO I=8,1,-1
     ZLS=ZLS*ZLT+A39(I)
  enddo
!
  SVEIHE_JANEV=EXP(ZLS)
!
  RETURN
END FUNCTION SVEIHE_JANEV
!-----------------------------
! 22Jun2001 fgtok -s r8_precision.sub "r8con.csh conversion"
! 22Jun2001 fgtok
