subroutine orbsmoo2
  !
  ! smooth radial profile outputs of monte carlo calculation --
  !   profiles whose normalizations are done in outptb2
  !
  ! (dmc mar 2004 -- smoothing moved to generated code (nbo_load) ...
  !  only "hole patch" smooth is left here).
  !
  ! subroutines used:  comput/bsmooh.for, subroutine r8bsmoop
  !
  ! the profiles are normalized in outptb2.
  !
  use nbi_com
  !
  !============
  implicit none
  integer :: isb,ie,ienmx,ien,ib
  !============
  real(fp) :: z1(mj)
  !
  !-----------
  !
  z1=1
  do isb=1,nsbeam
     if(.not.nlfbmfpp(isb)) then
        !
        do ie=1,nerngfi
           call r8bsmoop(btrape(1:mj,ie,isb),z1)
        end do
        call r8bsmoop(btrap(1:mj,isb),z1)
        !
        call r8bsmoop(be0cx(1:mj,isb),z1)
        call r8bsmoop(bv0cx(1:mj,isb),z1)
        if(nsigexc_use.gt.0) then
           call r8bsmoop(excitr(1:mj,isb),z1)
        end if
     end if                          ! mc species test
  end do                             ! species loop
  !
  !  dmc may 2003:  nclass outputs added.
  !
  do isb=1,nsbeam
     if(.not.nlfbmfpp(isb)) then
        ienmx=3
        if(nlfprod(isb)) ienmx=1
        do ien=1,ienmx
           call r8bsmoop(upbs_ien(1:mj,ien,isb),z1)
        end do
     end if
  end do
  !
  do ib=1,nbeam
     do ien=1,3
        call r8bsmoop(upb_ien(1:mj,ien,ib),z1)
     end do
  end do
  !
  return
end subroutine orbsmoo2
